<%
' Zenkichi.com
' Common functions
' By Chris Prine 8/21/08

' MySQL Database

databaseFullDSN = "DRIVER={MySQL ODBC 3.51 Driver};SERVER=zenkichi.db.2396606.hostedresource.com" _
& ";UID=zenkichi" _
& ";PASSWORD=Adam0987" _
& ";DATABASE=zenkichi;option=3; port=3306"


const zenAdminLogin="zenadmin"
const zenAdminPass="7jail39"
const zenAdminCookieName="ztoken"

const zenPressPath="/images/press"

zenPressPathAbs=server.MapPath(zenPressPath)
' --------------------------------------------------------------------------
' Database comm functions

function DBqueryArray(sqlStr, search)
	DBqueryArray=(DBqueryArrayFoundRows(sqlStr, search)>0)
end function

function DBqueryArrayFoundRows(sqlStr, search)
   ' General database query
   ' input
   '		sqlStr	SQL string query
   ' output
   '		search	results of query in array
   '	returns boolean for results
	DBqueryArrayFoundRows = 0
	if debugArray then
		debugDump(sqlStr)
	else
		dim conntemp, rstemp
		set rstemp=Server.CreateObject("ADODB.recordset")
		'set conntemp=server.createobject("adodb.connection")
		
		'conntemp.open databaseFullDSN
		
		set rstemp=zenDBobj.execute(sqlStr)
		
		if NOT rstemp.eof then
			search = rstemp.getrows
			rstemp.close
			
			if InStr(sqlStr,"SQL_CALC_FOUND_ROWS") then
				set rstemp=zenDBobj.execute("SELECT FOUND_ROWS() AS A")
				DBqueryArrayFoundRows=MyCint(rstemp.fields.item("A"))
				rstemp.close
			else
				DBqueryArrayFoundRows = 1
			end if		
		else
			rstemp.close
		end if

	end if
end function

function DBQuerySingle(sqlStr)
	' Returns single value
	' Usually used for getting a single aggregate value
	dim rstemp, returnValue
	set rstemp=Server.CreateObject("ADODB.recordset")
	set rstemp=zenDBobj.execute(sqlStr)
		
	if NOT rstemp.eof then
		returnValue=rstemp.fields.item(0)
	else
		returnValue=null
	end if
	
	set rstemp=nothing
	DBQuerySingle=returnValue
end function

function DBqueryObject(sqlStr, search)
   ' General database query
   ' input
   '		sqlStr	SQL string query
   ' output
   '		search	results of query in recordset
   '	returns boolean for results
	dim conntemp
	
	'set conntemp=server.createobject("ADODB.connection")
	set search=nothing
	set search=Server.CreateObject("ADODB.recordset")
	'zenDBobj.open databaseFullDSN
		
	set search=zenDBobj.execute(sqlStr)
	
	if NOT search.eof then
		DBqueryObject = true
	else
		DBqueryObject = false
   	end if
	
	'conntemp.close
end function

sub DBOpen(dbObj)
	' Call at top of page
	set dbObj=nothing
	set dbObj=server.createobject("ADODB.connection")
	dbObj.open databaseFullDSN
end sub

sub DBClose(dbObj)
	' Call at end of page
	dbObj.close
	set dbObj=nothing
end sub

function DBcall(ais_sql)
'General database query
'aissql holds sql query
'mainly for inserts and updates where no info is returned
	if debugCall then
		debugDump(ais_sql)
	else
		dim rstemp
		set rstemp=zenDBobj.execute(ais_sql)
		set rstemp=zenDBobj.execute("SELECT LAST_INSERT_ID() AS lastid")
		DBcall = rstemp.fields.item("lastid")
		rstemp.close	
	end if
end function

' --------------------------------------------------------------------------
' Database input untainting

function DBsafe(str)
	' returns a value that can safely used in a SQL statement
	DBsafe = replace(replace(str&"", "'", "''"),"\","\\")
end function

function DBstring(str)
	' returns string that can be used as a value in a SQL statement
	if str & "" = "" then DBstring = "NULL" else DBstring = "'" & DBsafe(str) & "'"
end function

function DBnumber(str)
	' returns string that can be converted to numerical value
	if Not IsNumeric(str & "") then 
		DBnumber = "0"
	else 
		DBnumber = DBsafe(replace(str, ",", ""))
	end if
end function

function DBdate(str)
	DBdate=DBstring(dateToMysql(str))
end function


function dateToMysql(theDate)
	' convert MS date format to MySQL Datetime (YYYY-MM-DD HH:MM:SS)
	dim outResult
	outResult = ""
	
	if isDate(theDate&"") then
		outResult = year(theDate) & "-" & LeadingZeros(month(theDate),2) & "-" & LeadingZeros(day(theDate),2) & " " _
		& LeadingZeros(hour(theDate),2) & ":" & LeadingZeros(minute(theDate),2) & ":" & LeadingZeros(second(theDate),2)
	end if
	dateToMysql = outResult
	
end function

function LeadingZeros(theNumber, numLength)
	' pad number with leading zeroes until the string length equals numLength
	dim outResult
	outResult = theNumber&""
	
	do while len(outResult)<numLength
		outResult = "0" & outResult
	loop
	
	LeadingZeros = outResult
end function

' --------------------------------------------------------------------------
' Misc 

function reg_match(reg_pattern, reg_string)
	dim outString,reObj
	outString=false
	if reg_string>"" then
		Set reObj = New RegExp
	
		reObj.Pattern = reg_pattern
		reObj.Global = True
	
		outString = reObj.Test(reg_string)
		Set reObj = nothing
	end if
	reg_match=outString
	
end function

function reg_replace(reg_pattern, reg_string, reg_replacement)
	dim outString,reObj
	outString=""
	if reg_string>"" then
		Set reObj = New RegExp
	
		reObj.Pattern = reg_pattern
		reObj.Global = True
	
		outString = reObj.Replace(reg_string,reg_replacement)
		Set reObj = nothing
	end if
	reg_replace=outString
	
end function

function textFieldReady(stringInput)
	dim theInp
	theInp=stringInput&""
	if theInp>"" then	
		theInp=replace(theInp, """", "&quot;")
	end if
	textFieldReady=theInp
end function

sub printHiddenInput(fname, fvalue)
	dim formatField
	formatField=fvalue&""
	formatField = replace(formatField, """", "&quot;")
	response.Write("<input type=""hidden"" name=""" & fname & """ value=""" & formatField & """>" & vbcrlf)
end sub

function returnAdminToken()
	dim tmpArr, returnString
	returnString=""
	if DBQueryArray("SELECT CAST(SHA(" & DBString(zenAdminLogin & zenAdminPass) & ") AS CHAR)", tmpArr) then
		returnString = Cstr(tmpArr(0,0))
	end if
	returnAdminToken=returnString
end function

function textToHTML(textString)
	dim outString
	outString=textString&""
	outString=replace(outString, vbcrlf, "<br>")
	outString=replace(outString, vbtab, "&#09;")
	outString=replace(outString, "  ", "&nbsp; ")
	
	textToHTML=outString
end function

function pressImagePath(pressRecordNo)
	pressImagePath=zenPressPath & "/" & pressRecordNo & ".jpg"
end function

function pressImageThumbPath(pressRecordNo)
	pressImageThumbPath=zenPressPath & "/" & pressRecordNo & "thumb.jpg"
end function

function fieldToTextArea(inputText)
	dim copyText
	
	copyText=inputText&""
	copyText=replace(copyText, "<br>", vbcrlf)
	copyText=replace(copyText, "&#09;", vbtab)
	copyText=replace(copyText, "&nbsp;", " ")
	copyText=replace(copyText, "<", "&lt;")
	copyText=replace(copyText, ">", "&gt;")
	
	fieldToTextArea=copyText
end function
%>

<%
menuPages="index.asp,reservation.asp,menu.asp,qanda.asp,press.asp"
menuTitles="Home,Reservation,Menu,Q &amp; A,Press"
arrMenu=split(menuPages,",")
arrTitles=split(menuTitles,",")

currentPage = lcase(reg_replace("^/?(?:[^/]+/)+([^/]+)$", Request.ServerVariables("PATH_INFO"), "$1"))
currentPage = lcase(reg_replace("^/?([^/]+)$", currentPage, "$1"))
flashVars=""
for m=0 to 4
	targetURL=arrMenu(m)
	if targetURL=currentPage then flashVars="curtab=" & (m+1)
next
dim zenDBobj
call DBOpen(zenDBobj)
%>
<html>
<head>
<title>Zenkichi - Modern Japanese Brasserie - Brooklyn, NY</title>
<meta name="generator" content="Quality Web Solutions Inc.">
<meta name="keywords" content="Japanese food, Williamsburg, Brooklyn, New York" />
<meta name="description" content="Zenkichi: A modern Japanese brasserie located in Williamsburg, Brooklyn, New York." />

<link href="http://www.opentable.com/r/feed.css" rel="styleSheet" type="text/css">
<link rel="stylesheet" type="text/css" href="zenkichi.css" media="screen" />

<link rel="shortcut icon" type="image/x-icon" href="images/zenkichi.ico" />
<script language="javascript">AC_FL_RunContent = 0;</script>
<script src="AC_RunActiveContent.js" language="javascript"></script>

<script type="text/javascript" language="JavaScript" src="js/zenkichi.js"></script>

<script type="text/javascript" src="js/prototype.js"></script>
<script type="text/javascript" src="js/scriptaculous.js?load=effects,builder"></script>
<script type="text/javascript" src="js/lightbox.js"></script>
<link rel="stylesheet" href="css/lightbox.css" type="text/css" media="screen" />

</head>
<body>
<div align="center">
<table id="topbox"><tr>
<td><a href="/"><img src="images/zenkichi.gif" alt="Zenkichi Modern Japanese Brasserie" title="Zenkichi" id="titleimg"></a></td>
<td id="topinfo">Phone 718-388-8985<br>77 N 6th St, Brooklyn, NY 11211, <a href="javascript: zenShowMap();">Map</a>
</td>
</tr></table>

<table id="mainbox">
<tr><td id="sidemenu">
<!--url's used in the movie-->
<!--text used in the movie-->
<!--
<p align="center"><font face="Arial" size="12" color="#000000" letterSpacing="0.000000" kerning="1"><b>test</b></font></p>
<p align="center"><font face="Arial" size="12" color="#000000" letterSpacing="0.000000" kerning="1"><b>test</b></font></p>
<p align="center"><font face="Arial" size="12" color="#000000" letterSpacing="0.000000" kerning="1"><b>test</b></font></p>
<p align="center"><font face="Arial" size="12" color="#000000" letterSpacing="0.000000" kerning="1"><b>test</b></font></p>
<p align="center"><font face="Arial" size="12" color="#000000" letterSpacing="0.000000" kerning="1"><b>test</b></font></p>
<p align="right"></p>
-->
<!-- saved from url=(0013)about:internet -->
<script language="javascript">
	if (AC_FL_RunContent == 0) {
		alert("This page requires AC_RunActiveContent.js.");
	} else {
		AC_FL_RunContent(
			'codebase', 'http://download.macromedia.com/pub/shockwave/cabs/flash/swflash.cab#version=9,0,0,0',
			'width', '380',
			'height', '425',
			'src', 'zenmenuClass2',
			'quality', 'high',
			'pluginspage', 'http://www.macromedia.com/go/getflashplayer',
			'align', 'middle',
			'play', 'true',
			'loop', 'true',
			'scale', 'showall',
			'wmode', 'window',
			'devicefont', 'false',
			'id', 'zenmenuClass2',
			'bgcolor', '#000000',
			'name', 'zenmenuClass2',
			'menu', 'true',
			'allowFullScreen', 'false',
			'allowScriptAccess','sameDomain',
			'movie', 'zenmenuClass2',
			'salign', '',
			'flashvars','<%=FlashVars%>'
			); //end AC code
	}
</script>
<noscript>
	<object classid="clsid:d27cdb6e-ae6d-11cf-96b8-444553540000" codebase="http://download.macromedia.com/pub/shockwave/cabs/flash/swflash.cab#version=9,0,0,0" width="380" height="425" id="zenmenuClass2" align="middle">
	<param name="allowScriptAccess" value="sameDomain" />
	<param name="allowFullScreen" value="false" />
	<param name="flashVars" value="<%=FlashVars%>" />
	<param name="movie" value="zenmenuClass2.swf" /><param name="quality" value="high" /><param name="bgcolor" value="#000000" />	<embed src="zenmenuClass2.swf" quality="high" bgcolor="#000000" width="380" height="425" name="zenmenuClass2" align="middle" allowScriptAccess="sameDomain" allowFullScreen="false" type="application/x-shockwave-flash" pluginspage="http://www.macromedia.com/go/getflashplayer" flashvars="<%=FlashVars%>" />
	</object>
</noscript>
</td>

<td id="infobox"><div id="infocontent">
<div id="infobuffer">


<h2>Menu</h2>
<%
if DBQueryArray("SELECT lMenuID,sMenu FROM tblMenu ORDER BY lMenuOrder,lMenuID", arrMenu) then
	response.write("<table id=""foodmenu"">")
	for m=0 to ubound(arrMenu,2)
		response.write("<tr><td colspan=""2"" class=""mtitle"">" & arrMenu(1,m) & "</td></tr>")
		
		if DBqueryArray("SELECT sMenuItem,sMenuItemPrice,sMenuItemDesc FROM tblMenuItem WHERE lMenuID=" & arrMenu(0,m) & " ORDER BY lMenuItemOrder,lMenuItemID", arrMItem) then
			for i=0 to ubound(arrMItem,2)
				response.write("<tr><td class=""mitem"">" & textToHTML(arrMItem(0,i)) & "</td><td align=""right"">" & arrMItem(1,i) & "</td></tr>")
				
				if arrMItem(2,i)>"" then
					response.write("<tr><td class=""mdetail"" colspan=""2"">" & textToHTML(arrMItem(2,i)) & "</td></tr>")
				end if
			next
		end if
		
		
	next
	
	response.write("</table>")
end if
%>
<%
call DBClose(zenDBobj)
%>
</div></div></td></tr></table>

<div id="footer">&copy; 2008 Zenkichi New York. All Rights Reserved.</div>
</div>
<!-- Web design by Akimasa Mituishi. Programming by Quality Web Solutions Inc -->
</body>
</html>